Jump to content
  • entries
    646
  • comments
    2,571
  • views
    865,636

Step 2 - Timers

SpiceWare

2,220 views

In Step 1 I used loops of sta WSYNC commands to delay the program so that Vertical Blank and OverScan would last for the proper duration. That method works fine when all we want to do is generate a static display, but as soon as we start to add game logic that won't work out so well.

 

The problem with the game logic is there will be so many different paths the code can take that it is nearly impossible for us to know how long the code ran, and thus we won't know how many scanlines we need to delay before the next section of code can run. As an example, if the player isn't moving the joystick then none of the "move player" logic will run. If the player is moving the joystick left and up then the "move horizontal" and "move vertical" logic will run. If the player is only holding the joystick left then only the "move horizontal" logic will run.

 

Fortunately for us, the Atari 2600 contains a RIOT chip. That acronym stands for RAM, Input/Output and Timer. We're interested in the Timer for this update to Collect, we'll look at RAM and I/O in a later update.

 

First thing I changed was OverScan. The original routine looked like this:

OverScan:
        sta WSYNC   ; Wait for SYNC (halts CPU until end of scanline)
        lda #2      ; LoaD Accumulator with 2 so D1=1
        sta VBLANK  ; STore Accumulator to VBLANK, D1=1 turns image output off
    
        ldx #27     ; LoaD X with 27
osLoop:
        sta WSYNC   ; Wait for SYNC (halts CPU until end of scanline)
        dex         ; DEcrement X by 1
        bne osLoop  ; Branch if Not Equal to 0
        rts         ; ReTurn from Subroutine
 

 

 

So what we want to do is set a timer that will go off after 27 scanlines to pass. There's 76 cycles of time per scanline, so we need the timer to go off after 2052 cycles have passed. When we set the timer, we also select how frequently the timer will decrement in value. RIOT has options to decrement the timer every 1, 8, 64 or 1024 cycles.

 

The timer is set using a single byte, so it can only be set to any value from 0 to 255. As such, we know we can't use decrement every 1 cycle as 2052 is too large. So let's check if decrement every 8 cycles will work:

2052/8 = 256.5

 

Almost, but 256 won't fit so we're going to have to use the decrement every 64 cycles option. To figure out the initial value to set the timer to, use this equation:

(scanlines * 76) / 64

 

The new OverScan routine that uses the timer looks like this:

OverScan:
        sta WSYNC   ; Wait for SYNC (halts CPU until end of scanline)
        lda #2      ; LoaD Accumulator with 2 so D1=1
        sta VBLANK  ; STore Accumulator to VBLANK, D1=1 turns image output off
        lda #32     ; set timer for 27 scanlines, 32 = ((27 * 76) / 64)
        sta TIM64T  ; set timer to go off in 27 scanlines
    
    ; game logic will go here
    
OSwait:
        sta WSYNC   ; Wait for SYNC (halts CPU until end of scanline)
        lda INTIM   ; Check the timer
        bne OSwait  ; Branch if its Not Equal to 0
        rts         ; ReTurn from Subroutine
 

 

 

For Vertical Blank we're going to set up the timer a little different. There's time in VerticalSync we can utilize, so we'll set the timer there - look for the code using ldx and stx:

VerticalSync:
        lda #2      ; LoaD Accumulator with 2 so D1=1
        ldx #49     ; LoaD X with 49
        sta WSYNC   ; Wait for SYNC (halts CPU until end of scanline)
        sta VSYNC   ; Accumulator D1=1, turns on Vertical Sync signal
        stx TIM64T  ; set timer to go off in 41 scanlines (49 * 64) / 76
        sta WSYNC   ; Wait for Sync - halts CPU until end of 1st scanline of VSYNC
        sta WSYNC   ; wait until end of 2nd scanline of VSYNC
        lda #0      ; LoaD Accumulator with 0 so D1=0
        sta WSYNC   ; wait until end of 3rd scanline of VSYNC
        sta VSYNC   ; Accumulator D1=0, turns off Vertical Sync signal
        rts         ; ReTurn from Subroutine 
 

 

 

We're also going to check the timer in the Kernel so we can start drawing the screen as soon as it goes off:

Kernel:
        sta WSYNC       ; Wait for SYNC (halts CPU until end of scanline)
        lda INTIM       ; check the timer
        bne Kernel      ; Branch if its Not Equal to 0
    ; turn on the display
        sta VBLANK      ; Accumulator D1=0, turns off Vertical Blank signal (image output on)
    
    ; draw the screen
        ldx #192        ; Load X with 192
KernelLoop:
        sta WSYNC       ; Wait for SYNC (halts CPU until end of scanline)
        stx COLUBK      ; STore X into TIA's background color register
        dex             ; DEcrement X by 1
        bne KernelLoop  ; Branch if Not Equal to 0
        rts             ; ReTurn from Subroutine
 

 

 

For the moment, these changes leave VerticalBlank with nothing to do:

VerticalBlank:
        rts             ; ReTurn from Subroutine
 

 

 

ROM

collect_20140625.bin

 

Source

Collect_20140625.zip

 

COLLECT TUTORIAL NAVIGATION

<PREVIOUS> <INDEX> <NEXT>

  • Like 1


3 Comments


Recommended Comments

Good Evening. Could you please elaborate on what these instructions do?

 

macro.h

 

SEG.U VARS

 

Thanks!

Share this comment


Link to comment

macro.h is a file that gets included into your source code as though you'd typed it in yourself. It contains a number of pre-written routines that can be handy to use. An example would be the macro VERTICAL_SYNC. If you use it, then the following code will be dropped in your program wherever you typed in VERTICAL_SYNC:

 

 

                LDA #$02            ; A = VSYNC enable
                STA WSYNC           ; Finish current line
                STA VSYNC           ; Start vertical sync
                STA WSYNC           ; 1st line vertical sync
                STA WSYNC           ; 2nd line vertical sync
                LSR                 ; A = VSYNC disable
                STA WSYNC           ; 3rd line vertical sync
                STA VSYNC           ; Stop vertical sync 

Share this comment


Link to comment

SEG.U VARS is used to specify an uninitialized segment with the name of VARS. The key thing about that, from dasm.txt (the instruction file for dasm), is:

 

Unitialized segments produce no output and have no restrictions.

That means whatever's after SEG.U does not end up in the ROM file. Here we're using it to allocate RAM usage.

  SEG.U VARS
  ORG $80 ; start of RAM
Score: ds 2
DigitOnes: ds 2
DigitTens: ds 2
...

Instead you could do this:

Score = $80
DigitOnes = $82
DigitTens = $84
...
but it becomes tedious (and error prone) to manually keep track of RAM usage yourself.

Share this comment


Link to comment
Guest
Add a comment...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

Loading...
  • Recently Browsing   0 members

    No registered users viewing this page.

×
×
  • Create New...